Ticore's Blog

AS3 - BitmapText 程式分享

2008-07-05T20:07:00.008+08:00

由於 Flash Player 一直以來都無法對系統字體的文字作旋轉與不規則形狀遮罩
可是到了 Flash Player 9 AS3，可以將文字繪製成點陣圖
也可以自行繼承內建類別 Sprite, TextField 等
於是想到做一個 TextField Wrapper，提供系統文字的點陣化功能
藉以達到文字可旋轉、套用不規則遮罩

其實這個 BitmapText 程式去年就已經寫了
主要是出於研究目的
專案一次也沒有用到過
沒想到最近新出的 Flash Player 10 beta 文字引擎
已經可以使用系統字體作旋轉了
倘若再不把這程式拿出來使用一下，恐怕就這樣永不見天日了~~><

主要是包含兩個類別 TextWrapper, BitmapText
TextWrapper 只是 TextField 的外覆類別
真正在做點陣繪圖的是 BitmapText
由於 AS3 TextField 成員屬性與方法相當多
我已經很盡量的複寫大部分的方法了

TextWrapper Class：

/*
TextWrapper AS3 v0.0.2
 
Date: 2007.04.25
作者: Ticore Shih
Blog：http://ticore.blogspot.com
EMail: swl@ms53.url.com.tw
 
v0.0.1
繼承 Sprite 包覆一個 TextField
 
v0.0.2
增加 TextField 一般性方法
*/

package com.ticore.text {
 
 import flash.geom.*;
 import flash.display.*;
 import flash.text.*;
 import flash.events.*;
 
 public class TextWrapper extends Sprite {
  //
  // Protected Property
  //
  protected var _txt_:TextField;
  //
  // Constructor
  //
  public function TextWrapper() {
   init();
  }
  protected function init():void {
   _txt_ = new TextField();
   this.addChild(_txt_);
  }
  //
  // Override DisplayObject Property and Method
  //
  public override function set width(w:Number):void {
   _txt_.width = w;
  }
  public override function get width():Number {
   return _txt_.width;
  }
  
  public override function set height(h:Number):void {
   _txt_.height = h;
  }
  public override function get height():Number {
   return _txt_.height;
  }
  //
  // Proxy Common TextField Property
  //
  public function set antiAliasType(value:String):void {
   _txt_.antiAliasType = value;
  }
  public function get antiAliasType():String {
   return _txt_.antiAliasType;
  }
  
  public function set autoSize(value:String):void {
   _txt_.autoSize = value;
  }
  public function get autoSize():String {
   return _txt_.autoSize;
  }
  
  public function set gridFitType(value:String):void {
   _txt_.gridFitType = value;
  }
  public function get gridFitType():String {
   return _txt_.gridFitType;
  }
  
  public function set htmlText(value:String):void {
   _txt_.htmlText = value;
  }
  public function get htmlText():String {
   return _txt_.htmlText;
  }
  
  public function set restrict(value:String):void {
   _txt_.restrict = value;
  }
  public function get restrict():String {
   return _txt_.restrict;
  }
  
  public function set text(txt:String):void {
   _txt_.text = txt;
  }
  public function get text():String {
   return _txt_.text;
  }
  
  public function set type(type:String):void {
   _txt_.type = type;
  }
  public function get type():String {
   return _txt_.type;
  }
  
  
  public function set backgroundColor(value:uint):void {
   _txt_.backgroundColor = value;
  }
  public function get backgroundColor():uint {
   return _txt_.backgroundColor;
  }
  
  public function set borderColor(value:uint):void {
   _txt_.borderColor = value;
  }
  public function get borderColor():uint {
   return _txt_.borderColor;
  }
  
  public function set textColor(value:uint):void {
   _txt_.textColor = value;
  }
  public function get textColor():uint {
   return _txt_.textColor;
  }
  
  
  public function get bottomScrollV():int {
   return _txt_.bottomScrollV;
  }
  
  public function get caretIndex():int {
   return _txt_.caretIndex;
  }
  
  public function get length():int {
   return _txt_.length;
  }
  
  public function get maxChars():int {
   return _txt_.maxChars;
  }
  
  public function get maxScrollH():int {
   return _txt_.maxScrollH;
  }
  
  public function get maxScrollV():int {
   return _txt_.maxScrollV;
  }
  
  public function get numLines():int {
   return _txt_.numLines;
  }
  
  public function get selectionBeginIndex():int {
   return _txt_.selectionBeginIndex;
  }
  
  public function get selectionEndIndex():int {
   return _txt_.selectionEndIndex;
  }
  
  
  public function set sharpness(value:Number):void {
   _txt_.sharpness = value;
  }
  public function get sharpness():Number {
   return _txt_.sharpness;
  }
  
  public function set thickness(value:Number):void {
   _txt_.thickness = value;
  }
  public function get thickness():Number {
   return _txt_.thickness;
  }
  
  public function get textHeight():Number {
   return _txt_.textHeight;
  }
  public function get textWidth():Number {
   return _txt_.textWidth;
  }
  
  
  public function set alwaysShowSelection(value:Boolean):void {
   _txt_.alwaysShowSelection = value;
  }
  public function get alwaysShowSelection():Boolean {
   return _txt_.alwaysShowSelection;
  }
  
  public function set border(value:Boolean):void {
   _txt_.border = value;
  }
  public function get border():Boolean {
   return _txt_.border;
  }
  
  public function set condenseWhite(value:Boolean):void {
   _txt_.condenseWhite = value;
  }
  public function get condenseWhite():Boolean {
   return _txt_.condenseWhite;
  }
  
  public function set displayAsPassword(value:Boolean):void {
   _txt_.displayAsPassword = value;
  }
  public function get displayAsPassword():Boolean {
   return _txt_.displayAsPassword;
  }
  
  public function set embedFonts(value:Boolean):void {
   _txt_.embedFonts = value;
  }
  public function get embedFonts():Boolean {
   return _txt_.embedFonts;
  }
  
  public function set mouseWheelEnabled(value:Boolean):void {
   _txt_.mouseWheelEnabled = value;
  }
  public function get mouseWheelEnabled():Boolean {
   return _txt_.mouseWheelEnabled;
  }
  
  public function set multiline(value:Boolean):void {
   _txt_.multiline = value;
  }
  public function get multiline():Boolean {
   return _txt_.multiline;
  }
  
  public function set selectable(value:Boolean):void {
   _txt_.selectable = value;
  }
  public function get selectable():Boolean {
   return _txt_.selectable;
  }
  
  public function set useRichTextClipboard(value:Boolean):void {
   _txt_.useRichTextClipboard = value;
  }
  public function get useRichTextClipboard():Boolean {
   return _txt_.useRichTextClipboard;
  }
  
  public function set wordWrap(value:Boolean):void {
   _txt_.wordWrap = value;
  }
  public function get wordWrap():Boolean {
   return _txt_.wordWrap;
  }
  //
  // Proxy Common TextField Method
  //
  public function appendText(text:String):void {
   _txt_.appendText(text);
  }
  
  public function getCharBoundaries(charIndex:int):Rectangle {
   return _txt_.getCharBoundaries(charIndex);
  }
  
  public function getCharIndexAtPoint(x:Number, y:Number):int {
   return _txt_.getCharIndexAtPoint(x,y);
  }
  
  public function getFirstCharInParagraph(charIndex:int):int {
   return _txt_.getFirstCharInParagraph(charIndex);
  }
  
  public function getImageReference(id:String):DisplayObject {
   return _txt_.getImageReference(id);
  }
  
  public function getLineIndexAtPoint(x:Number, y:Number):int {
   return _txt_.getLineIndexAtPoint(x,y);
  }
  
  public function getLineIndexOfChar(charIndex:int):int {
   return _txt_.getLineIndexOfChar(charIndex);
  }
  
  public function getLineLength(lineIndex:int):int {
   return _txt_.getLineLength(lineIndex);
  }
  
  public function getLineMetrics(lineIndex:int):TextLineMetrics {
   return _txt_.getLineMetrics(lineIndex);
  }
  
  public function getLineOffset(lineIndex:int):int {
   return _txt_.getLineOffset(lineIndex);
  }
  
  public function getLineText(lineIndex:int):String {
   return _txt_.getLineText(lineIndex);
  }
  
  public function getParagraphLength(charIndex:int):int {
   return _txt_.getParagraphLength(charIndex);
  }
  
  public function replaceSelectedText(value:String):void {
   _txt_.replaceSelectedText(value);
  }
  
  public function replaceText(beginIndex:int, endIndex:int, newText:String):void {
   _txt_.replaceText(beginIndex,endIndex,newText);
  }
  
  public function setTextFormat(format:TextFormat, beginIndex:int = -1, endIndex:int = -1):void {
   _txt_.setTextFormat(format,beginIndex,endIndex);
  }
  public function getTextFormat(beginIndex:int = -1, endIndex:int = -1):TextFormat {
   return _txt_.getTextFormat(beginIndex,endIndex);
  }
  
  public function set defaultTextFormat(format:TextFormat):void {
   _txt_.defaultTextFormat = format;
  }
  public function get defaultTextFormat():TextFormat {
   return _txt_.defaultTextFormat;
  }
  
 }
}

BitmapText Class：

/*
BitmapText AS3 v0.0.4
 
Date: 2007.04.25
作者: Ticore Shih
Blog：http://ticore.blogspot.com
EMail: swl@ms53.url.com.tw
 
v0.0.1
利用 BitmapData draw TextFIeld
達到可以呈現旋轉文字的效果
 
v0.0.2
增加 TextField 一般性方法與屬性控制
增加 validate 屬性，減少不必要 draw 次數
 
TextField.autoSize 功能會有一些問題
TextField 大小會一直跳動，重複 draw 會發生多重影像
 
v0.0.3
增加 TextField 一般性方法與屬性控制
 
v0.0.4
重構將 TextWrapper 功能獨立為單一 Class
*/

package com.ticore.text {
 
 import flash.geom.*;
 import flash.display.*;
 import flash.text.*;
 import flash.events.*;
 import flash.filters.*;
 
 public class BitmapText extends TextWrapper {
  
  // Private Property
  private var _validate_:Boolean = true;
  private var magniFactor:Number = 3;
  private var blurFilter:BlurFilter;
  private var _useBitmapText_:Boolean = true;
  
  private var bmpData:BitmapData;
  private var bmp:Bitmap;
  
  public function BitmapText() {
   init();
  }
  protected override function init():void {
   super.init();
   _txt_.addEventListener(Event.CHANGE, onChange);
   bmp = new Bitmap();
   bmp.smoothing = true;
   bmp.scaleX = bmp.scaleY = 1 / magniFactor;
   this.addChild(bmp);
   _txt_.visible = false;
   this.addChild(_txt_);
   blurFilter = new BlurFilter(1 + magniFactor / 6, 1 + magniFactor / 6, BitmapFilterQuality.MEDIUM);
   validate = false;
   addEventListener(Event.ENTER_FRAME, onEnterFame);
  }
  //
  // Private Method
  //
  private function updateBmpData():void {
   if (bmpData) {
    bmpData.dispose();
   }
   bmpData = new BitmapData((width + 1) * magniFactor, (height + 1) * magniFactor, true, 0x00000000);
   bmp.bitmapData = bmpData;
   bmp.smoothing = true;
   validate = false;
  }
  
  private function onChange(eventObj:Event):void {
   validate = false;
  }
  
  private function onEnterFame(eventObj:Event):void {
   if (!validate) {
    draw();
   }
  }
  
  private function draw():void {
   if (bmpData == null) {
    updateBmpData();
   }

   if (bmpData.width < (width + 1) * magniFactor || bmpData.height < (height + 1) * magniFactor) {
    updateBmpData();
   }
   var rect:Rectangle = new Rectangle(_txt_.x, _txt_.y, _txt_.width, _txt_.height);
   bmpData.fillRect(bmpData.rect, 0x00000000);
   var xOffset:Number = -_txt_.x;

   var dev:Number = magniFactor / 3;
   bmpData.draw(_txt_, new Matrix(magniFactor, 0, 0, magniFactor, xOffset * magniFactor + 0, 0));
   bmpData.draw(_txt_, new Matrix(magniFactor, 0, 0, magniFactor, xOffset * magniFactor + dev, 0));
   bmpData.draw(_txt_, new Matrix(magniFactor, 0, 0, magniFactor, xOffset * magniFactor + 0, dev));
   bmpData.applyFilter(bmpData, bmpData.rect, new Point(0, 0), blurFilter);
   bmpData.draw(_txt_, new Matrix(magniFactor, 0, 0, magniFactor, xOffset * magniFactor + dev / 2, dev / 2));

   bmp.x = _txt_.x;
   bmp.y = _txt_.y;
   validate = true;
  }
  
  //
  // Public Method
  //
  public function set validate(value:Boolean):void {
   _validate_ = value;
  }
  public function get validate():Boolean {
   return _validate_;
  }
  
  public function set useBitmapText(value:Boolean):void {
   _useBitmapText_ = value;
   _txt_.visible = !value;
   bmp.visible = value;
  }
  public function get useBitmapText():Boolean {
   return _useBitmapText_;
  }
  //
  // Override Method
  //
  public override function set width(w:Number):void {
   super.width = w;
   validate = false;
  }
  public override function set height(h:Number):void {
   super.height = h;
   validate = false;
  }
  public override function appendText(text:String):void {
   super.appendText(text);
   validate = false;
  }
  public override function replaceSelectedText(value:String):void {
   super.replaceSelectedText(value);
   validate = false;
  }
  public override function replaceText(beginIndex:int, endIndex:int, newText:String):void {
   super.replaceText(beginIndex,endIndex,newText);
   validate = false;
  }
  public override function setTextFormat(format:TextFormat, beginIndex:int = -1, endIndex:int = -1):void {
   super.setTextFormat(format,beginIndex,endIndex);
   validate = false;
  }
  public override function set defaultTextFormat(format:TextFormat):void {
   super.defaultTextFormat = format;
   validate = false;
  }
  
  public override function set antiAliasType(value:String):void {
   super.antiAliasType = value;
   validate = false;
  }
  public override function set autoSize(value:String):void {
   super.autoSize = value;
   validate = false;
  }
  public override function set gridFitType(value:String):void {
   super.gridFitType = value;
   validate = false;
  }
  public override function set htmlText(value:String):void {
   super.htmlText = value;
   validate = false;
  }
  public override function set restrict(value:String):void {
   super.restrict = value;
   validate = false;
  }
  public override function set text(value:String):void {
   super.text = value;
   validate = false;
  }
  
  public override function set backgroundColor(value:uint):void {
   super.backgroundColor = value;
   validate = false;
  }
  public override function set borderColor(value:uint):void {
   super.borderColor = value;
   validate = false;
  }
  public override function set textColor(value:uint):void {
   super.textColor = value;
   validate = false;
  }
  
  public override function set sharpness(value:Number):void {
   super.sharpness = value;
   validate = false;
  }
  public override function set thickness(value:Number):void {
   super.thickness = value;
   validate = false;
  }
  
  public override function set alwaysShowSelection(value:Boolean):void {
   super.alwaysShowSelection = value;
   validate = false;
  }
  public override function set border(value:Boolean):void {
   super.border = value;
   validate = false;
  }
  public override function set condenseWhite(value:Boolean):void {
   super.condenseWhite = value;
   validate = false;
  }
  public override function set displayAsPassword(value:Boolean):void {
   super.displayAsPassword = value;
   validate = false;
  }
  public override function set embedFonts(value:Boolean):void {
   super.embedFonts = value;
   validate = false;
  }
  public override function set multiline(value:Boolean):void {
   super.multiline = value;
   validate = false;
  }
  public override function set selectable(value:Boolean):void {
   super.selectable = value;
   validate = false;
  }
  public override function set wordWrap(value:Boolean):void {
   super.wordWrap = value;
   validate = false;
  }
  
 }
}

測試程式如下：

import com.ticore.text.*;

var bmpTxt:BitmapText = new BitmapText();
this.addChild(bmpTxt);
bmpTxt.border = true;
bmpTxt.multiline = true;
bmpTxt.rotation = 0;
bmpTxt.wordWrap = true;
bmpTxt.rotation = 15;
bmpTxt.width = 320;
bmpTxt.height = 250;
bmpTxt.x = 170;
bmpTxt.y = 30;

var format:TextFormat = bmpTxt.getTextFormat();
format.font = "新細明體";
format.align = "center";

for (var i:Number = 6; i <= 22; ++i) {
 format.size = i;
 bmpTxt.defaultTextFormat = format;
 bmpTxt.appendText("Font Size " + format.size + "  新細明體\n");
}

原始檔案下載

實際執行效果擷圖：

看起來應該還不錯吧！
即使在旋轉狀態下也沒有很嚴重的鋸齒
我特別在繪製點陣圖步驟提升了解析度
並且作了偏移繪製，套用濾鏡
當然這些動作是會消耗效能的
所以只有在必要時才會進行重繪的動作

在 Flash 作點陣圖九宮格縮放技巧

2007-10-06T16:46:00.000+08:00

Ticore's Blog

Flash 8、9 雖然有支援 Scale 9 縮放功能
但是僅限於向量物件
MovieClip 的 Scale 9 設定對點陣圖並沒有效果
以下介紹一個技巧，可以讓 Flash Scale 9 功能也能應用在點陣圖上

先將點陣圖包成 MovieClip，並勾選 Scale 9 設定

將點陣圖打散成為向量填色區塊

沿著 Scale 9 Grid 劃線，將點陣圖填色區塊切割開

最後，把九個填色區塊個別包成群組，刪除切割用的線條
這樣該 MovieClip 便可以用 Scale 9 模式縮放了

Flash 點陣圖九宮格 (Scale 9) 縮放比較

Flex Embed 點陣圖檔小技巧

2007-10-06T14:43:00.000+08:00

Ticore's Blog

Flex 可以使用 Embed 標籤，指定外部圖檔素材
但是透過這種方式匯入的圖片預設是無抗鋸齒效果的
雖然可以自行用 AS3 重新以 smooth 方式 draw
不過實在太麻煩

先看看直接 Embed 圖檔的情況，有很嚴重的鋸齒

以下介紹利用 Flash 改善點陣圖鋸齒

將圖檔匯入 Flash，並且勾選 Allow smoothing 選項

將圖片包成一個 MovieClip，並輸出 SWF
在 Flex MXML 內指定 Embed 標籤

<?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml"
 width="120" height="112"
 backgroundImage="@Embed(source='assets.swf', symbol='fx')">
</mx:Application>

執行結果

ActionScript BitmapData.draw TextField Bug

2007-01-21T13:25:00.001+08:00

Ticore's Blog

問題描述：

使用 BitmapData.draw 繪制 TextField 點陣圖資料
該 TextField 使用非嵌入字體
且 draw 方法的 blendMode 參數非為 "normal"

同時使用者用滑鼠拖動應用程式視窗
或是打開應用程式控制選單(application control menu)
或是調整視窗大小
會造成該 Flash Movie 所在執行應用程式 (Flash Player、Browser、Flash IDE)
執行發生錯誤而終止

執行環境與條件：

ActionScript Version：1、2、3
SWF Version：8、9
Flash Player Version：8、9
Player Mode：StandAlone、Plugin、ActiveX、External
Browser：IE、Firefox
OS：Windows XP SP2 cht

ActionScript 2 Bug Demo：

import flash.display.*;
import flash.geom.*;

var root:MovieClip = this;
var txt:TextField = root.createTextField("txt", root.getNextHighestDepth(), 100, 50, 100, 100);

var bmp:BitmapData = new BitmapData(txt._width, txt._height, true, 0);
root.attachBitmap(bmp, root.getNextHighestDepth());

root.onEnterFrame = function() {
 bmp.draw(txt, new Matrix(1, 0, 0, 1), null, "add");
};

ActionScript 3 Bug Demo：

package {
 import flash.display.*;
 import flash.text.*;
 import flash.utils.*;
 import flash.geom.*;
 public class Main extends MovieClip {
  public var txt:TextField;
  public var bmp:BitmapData;
  public function Main () {
   txt = new TextField();
   txt.x = 100;
   txt.y = 50;
   txt.width = 100;
   txt.height = 100;
   bmp = new BitmapData(txt.width, txt.height, true, 0);
   setInterval(doDraw, 100);
  }
  public function doDraw () {
   bmp.draw(txt, new Matrix(1, 0, 0, 1), null, "add");
  }
 }
}

該 Bug 在以下版本 Windows Flash Player 測試會發生
Flash Player 9.0.15.0
Flash Player 9.0.16.0
Flash Player 9.0.28.0
Flash Player 9.0.45.0
Flash Player 9.0.47.0
Flash Player 9.0.60.120
Flash Player 9.0.60.235
Flash Player 9.0.64.0
Flash Player 9.0.115.0
Flash Player 9.0.124.0

相關連結：
Flash Player TextField Render Bug

動態讀取外部 PNG 作為 Alpha Mask

2006-11-09T13:42:00.002+08:00

Ticore's Blog

看到邦邦的問題
http://mmug.com.tw/forum/viewtopic.php?p=39227

測試出來的結果如下：

SWF URL:
http://riafiles.googlepages.com/gradientMask.swf

PNG URL:
http://riafiles.googlepages.com/gradientMask.png

關鍵應該是在設定 mask.cacheAsBitmap 的時機

ActionScript：

var maskURL:String = maskURL == null ? "gradientMask.png" : maskURL;

import flash.geom.*;

var maskee:MovieClip = this.createEmptyMovieClip("maskee", 100);
var masker:MovieClip = this.createEmptyMovieClip("masker", 200);

with (maskee) {
    colors = [0xFF0000, 0x0000FF];
    fillType = "radial"
    alphas = [100, 100];
    ratios = [0, 0xFF];
    spreadMethod = "reflect";
    interpolationMethod = "linearRGB";
    focalPointRatio = 0.9;
    matrix = new Matrix();
    matrix.createGradientBox(100, 100, Math.PI, 0, 0);
    beginGradientFill(fillType, colors, alphas, ratios, matrix, 
        spreadMethod, interpolationMethod, focalPointRatio);
    moveTo(0, 0);
    lineTo(550, 0);
    lineTo(550, 200);
    lineTo(0, 200);
    lineTo(0, 0);
    endFill();
}


var mcLoader:MovieClipLoader = new MovieClipLoader();
var mcLisObj:Object = {};
mcLisObj.onLoadInit = function(evtObj):Void{
 masker.cacheAsBitmap = true;
 masker.onPress = function():Void{
  startDrag(this);
 };
 masker.onRelease = masker.onReleaseOutside = function():Void{
  stopDrag();
 };
 maskee.cacheAsBitmap = true;
 maskee.setMask(masker);
};
mcLoader.addListener(mcLisObj);
mcLoader.loadClip(maskURL, masker);
// Ticore's Blog - http://ticore.blogspot.com/

Flash 8 AS2 數字進位轉換 Bug

2005-09-26T23:12:00.001+08:00

Ticore's Blog

由於新功能 BitmapData 出現
最近嘗試使用它來做一些資料轉換
常常用到 getPixel32
為了減少資料長度
把它轉成 16 或是 32 進位
一旦來源數字大小超過 0x80000000
轉換就會出現奇怪的字元

居然會出現以下的結果：

/*
  Ticore's Blog
  http://ticore.blogspot.com/
*/
trace(0x80000000.toString(16));
trace(0x80000000.toString(32));
trace(0x80000001.toString(16));
trace(0x80000001.toString(32));
// output:
// -(0000000
// -.000000
// -7fffffff
// -1vvvvvv

以前的版本好像也有一樣的狀況
只不過以前很少需要用到 32bit 整數轉換吧
javascript 與 actionscript 是很類似的東西
為什麼 javascript 就可以出現正確的結果~

相關連結：覆寫 AS2 Number.toString() 函式

Flash 8 AS2 點陣圖雙線性取樣函式

2005-09-21T20:05:00.001+08:00

Ticore's Blog

既然 Flash 8 可以直接操作點陣資料
那就可以用來實作一些影像處理的功能了
以下便是用 AS 作點陣圖雙線性重新取樣函式

不過這只是個人研究用的
畢竟AS跑大量迴圈還是比不上 Native 程式
所以並不具有實用的價值

真正欲做點陣圖縮放，可以使用 Matrix + draw
至少比 AS Implement 的快上100倍

/*
  Ticore's Blog
  http://ticore.blogspot.com/
*/
import flash.display.*;
import flash.geom.*;

//=======================================================================

function resizeTo(width:Number, height:Number, img:BitmapData):BitmapData {
 var temp:BitmapData = new BitmapData(width, height, true, 0xFF000000);
 
 var p0:Point = new Point();
 var p1:Point = new Point();
 var p2:Point = new Point();
 var p3:Point = new Point();
 var p4:Point = new Point();
 
 var c1:Number;
 var c2:Number;
 var c3:Number;
 var c4:Number;
 
 var a:Number;
 var r:Number;
 var g:Number;
 var b:Number;
 
 var dx:Number;
 var dy:Number;
 var cdx:Number;
 var cdy:Number;
 
 var dtl:Number;
 var dtr:Number;
 var dbl:Number;
 var dbr:Number;
 
 for(var i:Number = 0 ; i < width ; ++i){
  for(var j:Number = 0 ; j < height ; ++j){
   p0.x = i / width * (img.width -1);
   p0.y = j / height * (img.height - 1);
   p1.x = Math.floor(p0.x);
   p1.y = Math.floor(p0.y);
   p2.x = p1.x + 1;
   p2.y = p1.y;
   p3.x = p1.x + 1;
   p3.y = p1.y + 1;
   p4.x = p1.x;
   p4.y = p1.y + 1;
   
   c1 = img.getPixel32(p1.x, p1.y);
   c2 = img.getPixel32(p2.x, p2.y);
   c3 = img.getPixel32(p3.x, p3.y);
   c4 = img.getPixel32(p4.x, p4.y);
   
   dx = p0.x - p1.x;
   dy = p0.y - p1.y;
   cdx = 1 - dx;
   cdy = 1 - dy;
   
   dtl = dx * dy;
   dtr = cdx * dy;
   dbr = dx * cdy;
   dbl = cdx * cdy;
   
   a = ((c1 & 0xFF000000) * dbl
    + (c2 & 0xFF000000) * dbr
    + (c3 & 0xFF000000) * dtl
    + (c4 & 0xFF000000) * dtr) & 0xFF000000;
   
   r =  ((c1 & 0x00FF0000) * dbl
    + (c2 & 0x00FF0000) * dbr
    + (c3 & 0x00FF0000) * dtl
    + (c4 & 0x00FF0000) * dtr) & 0x00FF0000;
       
   g = ((c1 & 0x0000FF00) * dbl
    + (c2 & 0x0000FF00) * dbr
    + (c3 & 0x0000FF00) * dtl
    + (c4 & 0x0000FF00) * dtr) & 0x0000FF00;
   
   b = ((c1 & 0x000000FF) * dbl
    + (c2 & 0x000000FF) * dbr
    + (c3 & 0x000000FF) * dtl
    + (c4 & 0x000000FF) * dtr) & 0x000000FF;
   
   temp.setPixel32(i , j , a | r | g | b);
  }
 }
 return temp;
}

//=======================================================================

Hotspot Demo Video 2

2005-09-07T10:43:00.000+08:00

Ticore's Blog

這是利用Flash 8新功能BitmapData處理功能加上WebCam作出來的

利用雷射筆光源的開啟、關閉、移動
觸發事件
達到互動的效果

畫面上的三個MovieClip先對Hotspot註冊事件
才能接受Hotspot的事件呼叫
進行互動

Hotspot分析點陣資料之後
計算出雷射筆的位置
換算座標
最後發布事件